[Explicaţie: pregătirea unui scurt curs de Small Basic pentru copii a făcut să nu mă pot concentra să scriu pentru CNet.ro. Pentru a recupera, voi publica din programele pregătite pentru respectivul curs, cu speranţa că vor folosi cuiva – chiar dacă Small Basic nu e atât de popular.] Despre desenarea cu broasca ţestoasă am scris aici anul trecut. Acum doresc să revin cu alte câteva programe, simpluţe şi în acelaşi timp simpatice, adică bune pentru copiii care vor să înveţe cum să o conducă.

1. Să se scrie 82 în stilul indicatoarelor electronice (ca în captura de mai sus). Online aici.

GraphicsWindow.Width=300
GraphicsWindow.Height=270
GraphicsWindow.PenWidth=5
Turtle.Speed=9

' Acum scriu 8
Turtle.X=20
Turtle.Y=10
Turtle.TurnRight()
Turtle.Move(100)
Turtle.X=130
Turtle.Y=20
Turtle.TurnRight()
Turtle.Move(100)
Turtle.X=130
Turtle.Y=140
Turtle.Move(100)
Turtle.X=120
Turtle.Y=250
Turtle.TurnRight()
Turtle.Move(100)
Turtle.X=10
Turtle.Y=240
Turtle.TurnRight()
Turtle.Move(100)
Turtle.Y=120
Turtle.Move(100)
Turtle.X=20
Turtle.Y=130
Turtle.TurnRight()
Turtle.Move(100)

' Acum scriu 2
Turtle.X=170
Turtle.Y=10
Turtle.Move(100)
Turtle.X=280
Turtle.Y=20
Turtle.TurnRight()
Turtle.Move(100)
Turtle.X=270
Turtle.Y=130
Turtle.TurnRight()
Turtle.Move(100)
Turtle.X=160
Turtle.Y=140
Turtle.TurnLeft()
Turtle.Move(100)
Turtle.X=170
Turtle.Y=250
Turtle.TurnLeft()
Turtle.Move(100)

2. Să se deseneze o serie de dreptunghiuri, desigur tot cu broasca, unul în interiorul celuilalt. Online aici.

Turtle.Speed=10
Turtle.PenUp()
latime=610
inaltime=430
Turtle.X=0
Turtle.Y=0
While (inaltime>0) And (latime>0)
  Turtle.PenUp()
  Turtle.X=Turtle.X+5
  Turtle.Y=Turtle.Y+5
  Turtle.PenDown()
  Turtle.TurnRight()
  Turtle.Move(latime)
  Turtle.TurnRight()
  Turtle.Move(inaltime)
  Turtle.TurnRight()
  Turtle.Move(latime)
  Turtle.TurnRight()
  Turtle.Move(inaltime)
  latime=latime-10
  inaltime=inaltime-10
EndWhile

3. Să se deseneze un poligon cu n laturi de lungime m. Online aici.

TextWindow.WriteLine("Câte laturi să aibă?")
laturi=TextWindow.ReadNumber()
TextWindow.WriteLine("Ce lungime pentru latură?")
lungime=TextWindow.ReadNumber()
unghi=360/laturi
GraphicsWindow.Width=500
GraphicsWindow.Height=500
Turtle.Speed=10
Turtle.X=10
Turtle.Y=250
For i=1 To laturi
  Turtle.Move(lungime)
  Turtle.Turn(unghi)
EndFor

4. Să se mute broasca de ici colo, aleator, cu urme de culori diferite. (Eu îi spun “broasca beată” şi copiilor le place la nebunie. 🙂 ) Online aici.

GraphicsWindow.Width=500
GraphicsWindow.Height=500
Turtle.Show()
Turtle.Speed=10
For i=1 To 100
  GraphicsWindow.PenColor=GraphicsWindow.GetRandomColor()
  Turtle.MoveTo(Math.GetRandomNumber(500),Math.GetRandomNumber(500))
EndFor